OpenVMS
システム管理者マニュアル

前へ 次へ 目次 索引

20.8.9.1 MONITOR.COM プロシージャの使用法

前回のブートで収集したデータから記録ファイルおよび要約ファイルを保存し，現在のブートのデータの連続記録を開始します。 例 20-7 のプロシージャは，記録ファイルをパージしない点に注意してください。

例 20-7 MONITOR.COM プロシージャ 

$ SET VERIFY 
$ ! 
$ !  MONITOR.COM 
$ ! 
$ !  This command file is to be placed in a cluster-accessible directory 
$ !  called SYS$MONITOR and submitted at system startup time as a detached 
$ !  process via SUBMON.COM.  For each node, MONITOR.COM creates, in 
$ !  SYS$MONITOR, a MONITOR recording file that is updated throughout the 
$ !  life of the boot. It also creates, in MON$ARCHIVE, a summary file from 
$ !  the recording file of the previous boot, along with a copy of that 
$ !  recording file.  Include logical name definitions for both cluster- 
$ !  accessible directories, SYS$MONITOR and MON$ARCHIVE, in SYSTARTUP.COM. 
$ ! 
$ SET DEF SYS$MONITOR 
$ SET NOON 
$ PURGE MONITOR.LOG/KEEP:2 
$ ! 
$ !  Compute executing node name and recording and summary file names 
$ !  (incorporating node name and date). 
$ ! 
$ NODE = F$GETSYI("NODENAME") 
$ SEP = "" 
$ IF NODE .NES. "" THEN SEP = "_" 
$ DAY = F$EXTRACT (0,2,F$TIME()) 
$ IF F$EXTRACT(0,1,DAY) .EQS. " " THEN DAY = F$EXTRACT(1,1,DAY) 
$ MONTH = F$EXTRACT(3,3,F$TIME()) 
$ ARCHFILNAM = "MON$ARCHIVE:"+NODE+SEP+"MON"+DAY+MONTH 
$ RECFIL = NODE+SEP+"MON.DAT" 
$ SUMFIL = ARCHFILNAM+".SUM" 
 
$ ! 
$ !  Check for existence of recording file from previous boot and skip 
$ !  summary if not present. 
$ ! 
$ OPEN/READ/ERROR=NORECFIL RECORDING 'RECFIL' 
$ CLOSE RECORDING 
$ ! 
$ ! 
$ !  Generate summary file from previous boot. 
$ ! 
$ MONITOR /INPUT='RECFIL' /NODISPLAY /SUMMARY='SUMFIL' - 
$ ALL_CLASSES+MODE/ALL+STATES/ALL+SCS/ITEM=ALL+SYSTEM/ALL+DISK/ITEM=ALL 
$ ! 
$ ! 
$ !  Compute subject string and mail summary file to cluster manager. 
$ ! 
$ ! 
$ A=""" 
$ B=" MONITOR Summary " 
$ SUB = A+NODE+B+F$TIME()+A 
$ MAIL/SUBJECT='SUB' 'SUMFIL' CLUSTER_MANAGER 
$ ! 
$ ! 
$ !  Archive recording file and delete it from SYS$MONITOR. 
$ ! 
$ COPY 'RECFIL' 'ARCHFILNAM'.DAT 
$ DELETE 'RECFIL';* 
$ ! 
$ NORECFIL: 
$ SET PROCESS/PRIORITY=15 
$ ! 
$ ! 
$ !  Begin recording for this boot.  The specified /INTERVAL value is 
$ !  adequate for long-term summaries; you might need a smaller value 
$ !  to get reasonable "semi-live" playback summaries (at the expense 
$ !  of more disk space for the recording file). 
$ ! 
$ MONITOR /INTERVAL=300 /NODISPLAY /RECORD='RECFIL' ALL_CLASSES 
$ ! 
$ ! 
$ !  End of MONITOR.COM 
$ !

20.8.9.2 SUBMON.COM プロシージャの使用法

例 20-8 のプロシージャは， SYSTARTUP.COM から独立プロセスとして MONITOR.COM をキューに登録し，現在のブートの継続記録を開始します。

例 20-8 SUBMON.COM プロシージャ 

$ SET VERIFY 
$ ! 
$ !  SUBMON.COM 
$ ! 
$ !  This command file is to be placed in a cluster-accessible directory 
$ !  called SYS$MONITOR.  At system startup time, for each node, it is 
$ !  executed by SYSTARTUP.COM, following logical name definitions for 
$ !  the cluster-accessible directories SYS$MONITOR and MON$ARCHIVE. 
$ ! 
$ ! 
$ !  Submit detached MONITOR process to do continuous recording. 
$ ! 
$ ! 
$ RUN   SYS$SYSTEM:LOGINOUT.EXE - 
        /UIC=[1,4]              - 
        /INPUT=SYS$MONITOR:MONITOR.COM  - 
        /OUTPUT=SYS$MONITOR:MONITOR.LOG - 
        /ERROR=SYS$MONITOR:MONITOR.LOG  - 
        /PROCESS_NAME="Monitor" - 
 
        /WORKING_SET=512 - 
        /MAXIMUM_WORKING_SET=512 - 
        /EXTENT=512/NOSWAPPING 
$ ! 
$ ! 
$ !  End of SUBMON.COM 
$ !

20.8.9.3 MONSUM.COM プロシージャの使用法

例 20-9 のプロシージャは，毎日のプライム・タイムのクラスタの要約を作成します。

例 20-9 MONSUM.COM プロシージャ 

$ SET VERIFY 
$ ! 
$ !  MONSUM.COM 
$ ! 
$ !  This command file is to be placed in a cluster-accessible directory 
$ !  called SYS$MONITOR and executed at the convenience of the cluster 
$ !  manager.  The file generates both 24-hour and "prime time" cluster 
$ !  summaries and resubmits itself to run each day at midnight. 
$ ! 
$ SET DEF SYS$MONITOR 
$ SET NOON 
$ ! 
$ !  Compute file specification for MONSUM.COM and resubmit the file. 
$ ! 
$ FILE = F$ENVIRONMENT("PROCEDURE") 
$ FILE = F$PARSE(FILE,,,"DEVICE")+F$PARSE(FILE,,,"DIRECTORY")+F$PARSE(FILE,,,"NAME") 
$ SUBMIT 'FILE' /AFTER=TOMORROW /NOPRINT 
$ ! 
$ !  Generate 24-hour cluster summary. 
$ ! 
$ ! 
$ MONITOR/INPUT=(SYS$MONITOR:*MON*.DAT;*,MON$ARCHIVE:*MON*.DAT;*) - 
  /NODISPLAY/SUMMARY=MONSUM.SUM - 
  ALL_CLASSES+DISK/ITEM=ALL+SCS/ITEM=ALL- 
  /BEGIN="YESTERDAY+0:0:0.00" /END="TODAY+0:0:0.00" /BY_NODE 
$ ! 
$ ! 
$ !  Mail 24-hour summary file to cluster manager and delete the file from 
$ !  SYS$MONITOR. 
$ ! 
$ ! 
$ MAIL/SUBJECT="Daily Monitor Clusterwide Summary" MONSUM.SUM CLUSTER_MANAGER 
$ DELETE MONSUM.SUM;* 
$ ! 
$ !  Generate prime-time cluster summary. 
$ ! 
$ ! 
$ MONITOR/INPUT=(SYS$MONITOR:*MON*.DAT;*,MON$ARCHIVE:*MON*.DAT;*) - 
  /NODISPLAY/SUMMARY=MONSUM.SUM - 
  ALL_CLASSES+DISK/ITEM=ALL+SCS/ITEM=ALL- 
  /BEGIN="YESTERDAY+9:0:0.00" /END="YESTERDAY+18:0:0.00" /BY_NODE 
$ ! 
$ ! 
$ !  Mail prime-time summary file to cluster manager and delete the file 
$ !  from SYS$MONITOR. 
$ ! 
$ ! 
$ MAIL/SUBJECT="Prime-Time Monitor Clusterwide Summary" MONSUM.SUM CLUSTER_MANAGER 
$ DELETE MONSUM.SUM;* 
$ ! 
$ !  End of MONSUM.COM 
$ !

このプロシージャの中の MAIL コマンドは，ファイルを CLUSTER_MANAGER というユーザに送信するように指定しています。 CLUSTER_MANAGER のところを実際のユーザ名または論理名に置き換えてください。

多くの場合，データは多量になるため，要約ファイルはできるだけプリントするようにします。

20.8.10 遠隔監視

MONITOR は，転送メカニズムとして TCP/IP と DECnet の両方を使用できます。 OpenVMS V7.0 以降では，TCP/IP を使用するためには， SYS$STARTUP:SYSTARTUP_VMS.COM ファイルの中で次のコマンドを実行して， TCP/IP サーバを起動しておく必要があります。 


$ @SYS$STARTUP:VPM$STARTUP.COM

DECnet は，ずっと作動し続けます。ネットワーク・オブジェクトは，要求の時に作成されます。

混合バージョンの OpenVMS Cluster システムにおける遠隔監視

MONITOR CLUSTER コマンドを発行する，または会話型の任意の MONITOR 要求で/NODE 修飾子を指定すると， OpenVMS Cluster システム内の任意のノードを開始することができます。

OpenVMS Cluster システムでの遠隔監視は， OpenVMS のバージョンが異なるノード間では，互換性がないことがあります。 表 20-11 に，遠隔監視のバージョンの互換性を示します。

表 20-11 OpenVMS Cluster システムでの遠隔の監視互換性
  OpenVMS Alpha
および VAX バージョン 6.n または 7.n 		OpenVMS Alpha バージョン 1.5 および VAX バージョン 5.n
OpenVMS Alpha および VAX バージョン 6. n または 7. n Yes No
OpenVMS Alpha バージョン 1.5 および VAX バージョン 5. n No Yes

互換性のない遠隔ノードを監視しようとすると，次のメッセージが表示されます。 


%MONITOR-E-SRVMISMATCH, MONITOR server on remote node is an incompatible version

このメッセージが表示されたら，弊社のサポート担当者に連絡し，この問題を解決するための修正キットを入手してください。修正キットをインストールする前でも，MONITOR を使って，遠隔ノードについてのデータを得ることができます。これを行うには，遠隔ノードについてのデータを記録してから MONITOR プレイバック機能を実行し，ローカル・ノードについてのデータを検査します。

OpenVMS Cluster システムにおいて遠隔ノードを監視する際には，もう1つの相違があります。OpenVMS バージョン 6.2 以降では，監視できるディスク数の制限が，レコードの出力については 799 から 909 に，表示と要約の出力については 799 から 1817 に増えました。ただし，OpenVMS バージョン 6.2 以降を実行している遠隔ノードを， OpenVMS バージョン 6.2 より前のバージョンが実行されているシステムで監視する場合は，制限値は 799 のままです。

MONITOR についての詳細は，『Compaq OpenVMS システム管理ユーティリティ・リファレンス・マニュアル』を参照してください。

第 21 章
資源使用状況の調査

本章では，システム資源がどのように使用されているかを調べる方法を説明します。この情報は，次のことに役立てることができます。

本章の内容

本章では，次の作業を説明します。

作業 参照箇所
調査対象の資源の表示 第 21.2 節
調査対象の資源の制御 第 21.3 節
会計情報ファイルの更新 第 21.4 節
会計情報ファイルの移動 第 21.5 節
資源使用量を示すレポートの生成 第 21.6 節
会計グループの設定 第 21.7 節
ディスク空間使用量の調査 第 21.8 節

さらに，次の項目について説明します。

項目 参照箇所
会計情報ファイル 第 21.1 節

21.1 会計情報ファイルについて

システムは，特定の資源の使用量に関する情報を収集し， 会計情報ファイルと呼ばれるファイルに記録します。このような情報の代表的なものに，各プリント・ジョブによって使用される CPU 時間があります。

省略時の設定において，情報収集の対象となる資源は，使用するコンピュータのモデルによって異なります。システム管理者は，どの資源の情報を収集するか制御することができます。たとえば，資源の使用量を調査する必要がない場合は，会計情報ファイルへの記録を停止することもできます ( 第 21.3 節 を参照)。

会計情報ファイルは OpenVMS Cluster 内の各ノードに存在します。各ノードの情報を記録しているファイルを，そのノードの現在の会計情報ファイルといいます。省略時の会計情報ファイルは SYS$MANAGER:ACCOUNTNG.DAT ですが，必要に応じて変更することもできます ( 第 21.5 節 を参照)。

会計情報ファイルには情報がバイナリ形式で記録されます。したがって，TYPE コマンドでこのファイルの内容を表示することはできません。内容を表示する場合は， ACCOUNTING ユーティリティを使用します ( 第 21.6 節 を参照)。

21.2 調査対象の資源の決定

現在，情報を収集している資源を決定する場合には， SHOW ACCOUNTING コマンドを使用します。 


$ SHOW ACCOUNTING

このコマンドは，次の 2 つのカテゴリについて，そのキーワードを表示します。

例 


$ SHOW ACCOUNTING
Accounting is currently enabled to log the following activities:
      PROCESS        any process termination
      IMAGE          image execution
      INTERACTIVE    interactive job termination
      LOGIN_FAILURE  login failures
      NETWORK        network job termination
      PRINT          all print jobs

この例のキーワードから，ローカル・ノードでは次の資源が調査対象になっていることが分かります。

21.3 調査対象の資源の制御

システム管理者は，会計情報ファイルにどの資源の情報を記録するかを制御することができます。調べる必要がない資源の記録を停止すれば，ディスク空間の使用量を減らすこともできます。

作業方法

  1. 調査対象にする資源を一時的に制御する場合は， SET ACCOUNTING コマンドで修飾子 /ENABLE または /DISABLE を次の形式で使用する。 


    SET ACCOUNTING/DISABLE[=(キーワード[,...])] /ENABLE[=(キーワード[,...])]


    キーワードは， 第 21.2 節 で説明したものと同じ。

  2. 調査対象にする資源を変更したい場合 (すなわち，再ブート後も同じ設定を使用したい場合) は，スタートアップ・ファイル SYS$MANAGER:SYSTART_VMS.COM にある SET ACCOUNTING の記述を変更する。

例

会話型プロセスおよびバッチ・プロセスによって使用されるものを除くすべての資源の記録を停止する場合は，次のコマンドを使用します。 


$ SET ACCOUNTING/DISABLE/ENABLE=(PROCESS,INTERACTIVE,BATCH)

/DISABLE 修飾子の後ろにはキーワードが付いていません。したがって，この修飾子によりすべての資源の記録が停止されます。次の /ENABLE 修飾子により，会話型プロセスおよびバッチ・プロセスによって使用される資源の記録が開始されます。

21.4 会計情報ファイルの更新

会計情報ファイルを更新する場合は，次のコマンドを使用します。 


$ SET ACCOUNTING/NEW_FILE

このコマンドにより，現在の会計情報ファイルがクローズし，新しいバージョンがオープンします。

現在の会計情報ファイルに書き込みを行おうとするときにエラーが検出されると，会計情報ファイルは自動的にクローズし，新しいバージョンがオープンします。

例

現在の会計情報ファイルをクローズして新しいバージョンをオープンし，さらに古いファイルの名前をWEEK_24_RESOURCES.DAT に変更します。古いファイルはその週に使用された資源の記録として使用することができます。 


$ SET ACCOUNTING/NEW_FILE
$ RENAME SYS$MANAGER:ACCOUNTNG.DAT;-1 WEEK_24_RESOURCES.DAT

21.5 会計情報ファイルの移動

システムを初めてインストールした場合，現在の会計情報ファイルは SYS$MANAGER:ACCOUNTNG.DAT となります。

このファイルは非常に大きくなるため，システムの性能が低下しないように，適切な時期にシステム・ディスクから移動することが大切です。

作業方法

  1. システム論理名テーブルにある ACCOUNTNG という論理名で使用するファイルを定義する。たとえば，次のようにする。 


    $ DEFINE ACCOUNTNG MYDISK:MYFILE.DAT/SYSTEM


    装置およびディレクトリを含む完全ファイル指定を使用する。

    注意
    2 つのノードの情報を 1 つの会計情報ファイルに情報を記録することはできません。それぞれのノードで定義した ACCOUNTING が同一のファイルを指している場合，各ノードごとに独自のバージョンがオープンします。

  2. 再ブート後も同じ定義を継続したい場合は，この定義を
    SYS$MANAGER:SYLOGICALS.COM ファイルに追加する。

  3. SET ACCOUNTING コマンドに /NEW_FILE を指定して，新しいファイルを準備する。 


    $ SET ACCOUNTING/NEW_FILE

例

現在の会計情報ファイルを MYDISK:MYFILE.DAT に変更する場合は，次のようにします。 


$ DEFINE ACCOUNTNG MYDISK:MYFILE.DAT/SYSTEM
$ SET ACCOUNTING/NEW_FILE

前へ 次へ 目次 索引