| 前へ | 次へ | 目次 | 索引 |
適切な特権を持っていれば， DECnet によってローカル・システムに接続されている任意のシステムから MONITOR データを収集することができます。収集中のデータは，同時にローカル・システム上に表示することができます。その場合，次の手順に従います。
$ ! $ ! * Enable MONITOR remote playback * $ ! $ MONITOR /NODISPLAY/RECORD=SYS$NET ALL_CLASSES |
DEFINE 遠隔ノード論理名 ノード名::タスク=モニタ |
ログイン・コマンド・プロシージャの中でアクセスしたいすべてのシステムの論理名を定義することもできる。
MONITOR/INPUT=遠隔ノード論理名 クラス名 |
MONITOR.COM ファイルを省略時の DECNET ディレクトリ以外のディレクトリに置き，アクセス制御文字列または代理のアカウントを使用して，これらのコマンド・ファイルを遠隔呼び出しすることも可能です。
MONITOR をローカル・システムで呼び出した場合は，遠隔システム上にコマンド・ファイル MONITOR.COM を実行するプロセスが生成されます。したがって，遠隔システムではこのプロセスに関連する CPU および DECnet のオーバヘッドが発生します。このオーバヘッドは，MONITOR.COM ファイルの中に /INTERVAL 修飾子とクラス名のリストを加えることによって制限できます。
混在バージョンのクラスタ・システムにおいて，遠隔で監視を行う方法については 第 20.8.10 項 で説明しています。
20.8.8 記録ファイルの更新
記録ファイルの更新は，プレイバックと記録の 2 つの操作を組み合わせて行われます。この機能を使用すると，記録ファイルのデータの量を減らすことができます。既存の記録ファイルをプレイバックする場合は， MONITOR のすべてのオプションを利用できます。したがって，記録されているデータから特定のクラス，時間帯，記録する間隔を選択することができます。
これらの操作により，記録されたデータの一部を削除した，サイズが小さな記録ファイルが新しく作成されます。収集する間隔を長くするとデータの量は少なくなり，それだけ新しい記録ファイルから表示または要約されるデータの精度は低くなります。この場合，平均の割合を示す値は影響されませんが，サンプル・データのサイズが小さいために，平均のレベルを示す値の精度は低くなります。次の例は，記録ファイルの更新方法を示しています。
$ SUBMIT MONREC.COM |
MONREC.COM は次のコマンドを含んでいます。
$ MONITOR/NODISPLAY/RECORD/INTERVAL=60 /BEGINNING=8:00/ENDING=16:00 DECNET,LOCK $ MONITOR/INPUT/NODISPLAY/RECORD DECNET |
最初のコマンドはバッチ形式で動作し，午前 8 時から午後 4 時までの間， 1 分ごとに DECnet とロック管理に関する情報を記録します。 2 番目のコマンドは最初のコマンドが完了すると発行され， MONITOR.DAT ファイルの新しいバージョンを作成して DECnet に関するデータだけを再記録します。
20.8.9 MONITOR の継続実行
MONITOR をバックグランド・プロセスとして継続して実行することにより，システムの性能に関する情報を記録したデータベースを構築することができます。 ここでは，クラスタ管理者として，マルチファイルのクラスタ全体の要約を作成するために使用できるプロシージャの例を示します。
このコマンド・プロシージャを自分のサイトに合うように，変更することができます。なお，SYSTARTUP.COM に論理名 SYS$MONITOR および MON$ARCHIVE を定義してからでないと，コマンド・ファイルを実行することはできません。
論理名 SYS$EXAMPLES が指すディレクトリに，データベースの構築に利用できる 3 つのコマンド・プロシージャが含まれています。これらのプロシージャのインストールおよび実行の方法は，各プロシージャの先頭のコメントに示されています。 表 20-10 で，これらのプロシージャについて簡単にまとめます。
| プロシージャ名 | 説明 |
|---|---|
| MONITOR.COM | 前回のブート時に作成された記録ファイルから要約ファイルを作成し，今回のブートの記録を開始する。記録の間隔は 10 分。 |
| MONSUM.COM | 複数のファイルから構成されるクラスタ全体の要約レポートを 2 種類作成して，システム管理者にメールする。一方のレポートには過去 24 時間の情報が記録され，もう一方のレポートには前日のプライム・タイム (午前 9 時から午後 6 時まで) の情報が記録される。このプロシージャは，毎日夜中に実行するように，自身をキューに再登録する。 |
| SUBMON.COM | MONITOR.COM を独立プロセスとして実行する。サイト別スタートアップ・コマンド・プロシージャから SUBMON.COM を起動する。 |
MONITOR で継続的にデータを記録しながら，特定の期間の要約レポートを作成することができます。 MONSUM.COM コマンド・プロシージャは毎晩夜中に実行され，
表 20-10 に示す複数のファイルから構成される 2 つの要約レポートを生成し，メールします。これらのレポートはファイルに保存されません。内容を残すためには，メール・ファイルから情報を抽出するか，レポートを保存するように MONSUM.COM コマンド・プロシージャを変更します。
20.8.9.1 MONITOR.COM プロシージャの使用法
前回のブートで収集したデータから記録ファイルおよび要約ファイルを保存し，現在のブートのデータの連続記録を開始します。 例 20-7 のプロシージャは，記録ファイルをパージしない点に注意してください。
| 例 20-7 MONITOR.COM プロシージャ |
|---|
$ SET VERIFY
$ !
$ ! MONITOR.COM
$ !
$ ! This command file is to be placed in a cluster-accessible directory
$ ! called SYS$MONITOR and submitted at system startup time as a detached
$ ! process via SUBMON.COM. For each node, MONITOR.COM creates, in
$ ! SYS$MONITOR, a MONITOR recording file that is updated throughout the
$ ! life of the boot. It also creates, in MON$ARCHIVE, a summary file from
$ ! the recording file of the previous boot, along with a copy of that
$ ! recording file. Include logical name definitions for both cluster-
$ ! accessible directories, SYS$MONITOR and MON$ARCHIVE, in SYSTARTUP.COM.
$ !
$ SET DEF SYS$MONITOR
$ SET NOON
$ PURGE MONITOR.LOG/KEEP:2
$ !
$ ! Compute executing node name and recording and summary file names
$ ! (incorporating node name and date).
$ !
$ NODE = F$GETSYI("NODENAME")
$ SEP = ""
$ IF NODE .NES. "" THEN SEP = "_"
$ DAY = F$EXTRACT (0,2,F$TIME())
$ IF F$EXTRACT(0,1,DAY) .EQS. " " THEN DAY = F$EXTRACT(1,1,DAY)
$ MONTH = F$EXTRACT(3,3,F$TIME())
$ ARCHFILNAM = "MON$ARCHIVE:"+NODE+SEP+"MON"+DAY+MONTH
$ RECFIL = NODE+SEP+"MON.DAT"
$ SUMFIL = ARCHFILNAM+".SUM"
$ !
$ ! Check for existence of recording file from previous boot and skip
$ ! summary if not present.
$ !
$ OPEN/READ/ERROR=NORECFIL RECORDING 'RECFIL'
$ CLOSE RECORDING
$ !
$ !
$ ! Generate summary file from previous boot.
$ !
$ MONITOR /INPUT='RECFIL' /NODISPLAY /SUMMARY='SUMFIL' -
$ ALL_CLASSES+MODE/ALL+STATES/ALL+SCS/ITEM=ALL+SYSTEM/ALL+DISK/ITEM=ALL
$ !
$ !
$ ! Compute subject string and mail summary file to cluster manager.
$ !
$ !
$ A="""
$ B=" MONITOR Summary "
$ SUB = A+NODE+B+F$TIME()+A
$ MAIL/SUBJECT='SUB' 'SUMFIL' CLUSTER_MANAGER
$ !
$ !
$ ! Archive recording file and delete it from SYS$MONITOR.
$ !
$ COPY 'RECFIL' 'ARCHFILNAM'.DAT
$ DELETE 'RECFIL';*
$ !
$ NORECFIL:
$ SET PROCESS/PRIORITY=15
$ !
$ !
$ ! Begin recording for this boot. The specified /INTERVAL value is
$ ! adequate for long-term summaries; you might need a smaller value
$ ! to get reasonable "semi-live" playback summaries (at the expense
$ ! of more disk space for the recording file).
$ !
$ MONITOR /INTERVAL=300 /NODISPLAY /RECORD='RECFIL' ALL_CLASSES
$ !
$ !
$ ! End of MONITOR.COM
$ !
|
20.8.9.2 SUBMON.COM プロシージャの使用法
例 20-8 のプロシージャは， SYSTARTUP.COM から独立プロセスとして MONITOR.COM をキューに登録し，現在のブートの継続記録を開始します。
| 例 20-8 SUBMON.COM プロシージャ |
|---|
$ SET VERIFY
$ !
$ ! SUBMON.COM
$ !
$ ! This command file is to be placed in a cluster-accessible directory
$ ! called SYS$MONITOR. At system startup time, for each node, it is
$ ! executed by SYSTARTUP.COM, following logical name definitions for
$ ! the cluster-accessible directories SYS$MONITOR and MON$ARCHIVE.
$ !
$ !
$ ! Submit detached MONITOR process to do continuous recording.
$ !
$ !
$ RUN SYS$SYSTEM:LOGINOUT.EXE -
/UIC=[1,4] -
/INPUT=SYS$MONITOR:MONITOR.COM -
/OUTPUT=SYS$MONITOR:MONITOR.LOG -
/ERROR=SYS$MONITOR:MONITOR.LOG -
/PROCESS_NAME="Monitor" -
/WORKING_SET=512 -
/MAXIMUM_WORKING_SET=512 -
/EXTENT=512/NOSWAPPING
$ !
$ !
$ ! End of SUBMON.COM
$ !
|
20.8.9.3 MONSUM.COM プロシージャの使用法
例 20-9 のプロシージャは，毎日のプライム・タイムのクラスタの要約を作成します。
| 例 20-9 MONSUM.COM プロシージャ |
|---|
$ SET VERIFY
$ !
$ ! MONSUM.COM
$ !
$ ! This command file is to be placed in a cluster-accessible directory
$ ! called SYS$MONITOR and executed at the convenience of the cluster
$ ! manager. The file generates both 24-hour and "prime time" cluster
$ ! summaries and resubmits itself to run each day at midnight.
$ !
$ SET DEF SYS$MONITOR
$ SET NOON
$ !
$ ! Compute file specification for MONSUM.COM and resubmit the file.
$ !
$ FILE = F$ENVIRONMENT("PROCEDURE")
$ FILE = F$PARSE(FILE,,,"DEVICE")+F$PARSE(FILE,,,"DIRECTORY")+F$PARSE(FILE,,,"NAME")
$ SUBMIT 'FILE' /AFTER=TOMORROW /NOPRINT
$ !
$ ! Generate 24-hour cluster summary.
$ !
$ !
$ MONITOR/INPUT=(SYS$MONITOR:*MON*.DAT;*,MON$ARCHIVE:*MON*.DAT;*) -
/NODISPLAY/SUMMARY=MONSUM.SUM -
ALL_CLASSES+DISK/ITEM=ALL+SCS/ITEM=ALL-
/BEGIN="YESTERDAY+0:0:0.00" /END="TODAY+0:0:0.00" /BY_NODE
$ !
$ !
$ ! Mail 24-hour summary file to cluster manager and delete the file from
$ ! SYS$MONITOR.
$ !
$ !
$ MAIL/SUBJECT="Daily Monitor Clusterwide Summary" MONSUM.SUM CLUSTER_MANAGER
$ DELETE MONSUM.SUM;*
$ !
$ ! Generate prime-time cluster summary.
$ !
$ !
$ MONITOR/INPUT=(SYS$MONITOR:*MON*.DAT;*,MON$ARCHIVE:*MON*.DAT;*) -
/NODISPLAY/SUMMARY=MONSUM.SUM -
ALL_CLASSES+DISK/ITEM=ALL+SCS/ITEM=ALL-
/BEGIN="YESTERDAY+9:0:0.00" /END="YESTERDAY+18:0:0.00" /BY_NODE
$ !
$ !
$ ! Mail prime-time summary file to cluster manager and delete the file
$ ! from SYS$MONITOR.
$ !
$ !
$ MAIL/SUBJECT="Prime-Time Monitor Clusterwide Summary" MONSUM.SUM CLUSTER_MANAGER
$ DELETE MONSUM.SUM;*
$ !
$ ! End of MONSUM.COM
$ !
|
このプロシージャの中の MAIL コマンドは，ファイルを CLUSTER_MANAGER というユーザに送信するように指定しています。 CLUSTER_MANAGER のところを実際のユーザ名または論理名に置き換えてください。
多くの場合，データは多量になるため，要約ファイルはできるだけプリントするようにします。
20.8.10 遠隔監視
MONITOR は，転送メカニズムとして TCP/IP と DECnet の両方を使用できます。 OpenVMS V7.0 以降では，TCP/IP を使用するためには， SYS$STARTUP:SYSTARTUP_VMS.COM ファイルの中で次のコマンドを実行して， TCP/IP サーバを起動しておく必要があります。
$ @SYS$STARTUP:VPM$STARTUP.COM |
DECnet は，ずっと作動し続けます。ネットワーク・オブジェクトは，要求の時に作成されます。
混合バージョンの OpenVMS Cluster システムにおける遠隔監視
MONITOR CLUSTER コマンドを発行する，または会話型の任意の MONITOR 要求で/NODE 修飾子を指定すると， OpenVMS Cluster システム内の任意のノードを開始することができます。
OpenVMS Cluster システムでの遠隔監視は， OpenVMS のバージョンが異なるノード間では，互換性がないことがあります。 表 20-11 に，遠隔監視のバージョンの互換性を示します。
| OpenVMS Alpha および VAX バージョン 6.n または 7.n |
OpenVMS Alpha バージョン 1.5 および VAX バージョン 5.n | |
|---|---|---|
| OpenVMS Alpha および VAX バージョン 6. n または 7. n | Yes | No |
| OpenVMS Alpha バージョン 1.5 および VAX バージョン 5. n | No | Yes |
互換性のない遠隔ノードを監視しようとすると，次のメッセージが表示されます。
%MONITOR-E-SRVMISMATCH, MONITOR server on remote node is an incompatible version |
このメッセージが表示されたら，弊社のサポート担当者に連絡し，この問題を解決するための修正キットを入手してください。修正キットをインストールする前でも，MONITOR を使って，遠隔ノードについてのデータを得ることができます。これを行うには，遠隔ノードについてのデータを記録してから MONITOR プレイバック機能を実行し，ローカル・ノードについてのデータを検査します。
OpenVMS Cluster システムにおいて遠隔ノードを監視する際には，もう1つの相違があります。OpenVMS バージョン 6.2 以降では，監視できるディスク数の制限が，レコードの出力については 799 から 909 に，表示と要約の出力については 799 から 1817 に増えました。ただし，OpenVMS バージョン 6.2 以降を実行している遠隔ノードを， OpenVMS バージョン 6.2 より前のバージョンが実行されているシステムで監視する場合は，制限値は 799 のままです。
MONITOR についての詳細は，『Compaq OpenVMS システム管理ユーティリティ・リファレンス・マニュアル』を参照してください。
| 前へ | 次へ | 目次 | 索引 |